22 HO=HO+40:VE=VE+6
110 HO=MAX(0,HO):HO=MIN(39,HO):VE=MAX(0,VE):VE=MIN(30,VE):PRINT CHR$(27)"Y"CHR$(32+VE)CHR$(32+HO);:RETURN
1000 A=5000:GOTO 20:REM *** LABOR 9/1 ***
1010 I=0:J=0:K=0:H1=HO:V1=VE:VZ=0.75:CN=0
1020 DIM P(1,32)
1030 P=4*ATN(1):R=0.999
1040 TA$=" weiter mit einer Taste >>"
1050 GOSUB 9000:REM zum Titelbid
1060 GOTO 2000
1069 REM Ton
1070 SD=1:SP=100:SV=10:GOSUB 400:RETURN
1997 REM ***********************
1998 REM     Ausgabe Text
1999 REM ***********************
2000 GOSUB 100:VE=0:HO=(H1-LEN(L$))/2:GOSUB 110:PRINT L$:PRINT 
2010 READ S$
2020 IF MID$(S$,1,1)="#" THEN 3000
2030 S$=S$+" "
2039 B$="":REM Textuntersuchung
2040 FOR I=1 TO LEN(S$)
2050 X$=MID$(S$,I,1)
2060 IF X$="@" THEN X$=","
2070 IF X$<>" " THEN B$=B$+X$:GOTO 2150
2080 GOSUB 120
2090 IF HO+LEN(B$)>H1-1 THEN PRINT 
2099 REM Textausgabe buchstabenweise
2100 IF B$="" THEN 2140
2110 FOR J=1 TO LEN(B$)
2120 PRINT MID$(B$,J,1);:GOSUB 1070
2130 NEXT J
2140 PRINT " ";:B$=""
2150 NEXT I
2160 GOTO 2010
2999 REM Sonderbehandlungen
3000 IF S$="#END" THEN 3130
3010 SS$=MID$(S$,1,3)
3020 IF SS$<>"#ZF" THEN 3080
3029 REM Zeichenfolge
3030 X$=MID$(S$,4):S$=""
3040 FOR I=0 TO H1-2
3050 S$=S$+X$
3060 NEXT I
3070 GOTO 2030
3080 IF SS$<>"#ZV" THEN 3110
3089 REM Zeilenvorschub
3090 PRINT:S$=MID$(S$,4)
3100 GOTO 2030
3109 REM Textpause fuer Bild
3110 GOSUB 3500
3120 GOTO 4000
3129 REM Ende
3130 HO=0:VE=V1-1:GOSUB 110
3140 READ S$:PRINT S$;
3150 GOSUB 250:GOSUB 250:GOSUB 250
3160 GOSUB 210
3170 GOTO 950:REM E N D E
3499 REM UP Taste 1
3500 GOSUB 200
3510 SD=50:GOSUB 450
3520 IF (IN) THEN 3560
3530 FOR I=0 TO 4:PRINT:GOSUB 1070:NEXT I
3540 HO=0:VE=V1-1:GOSUB 110:PRINT TA$;
3550 GOSUB 250:GOSUB 210
3560 FOR I=0 TO V1+2
3570 PRINT:GOSUB 1070
3580 NEXT I
3590 RETURN
3599 REM UP Taste 2
3600 CN=0:H=HO:V=VE
3610 HO=0:VE=0.95:SR$=TA$
3620 GOSUB 650:GOSUB 200:GOSUB 250
3630 HO=H:VE=V
3640 RETURN
3997 REM **************************
3998 REM Raumstation EXPERIMENT-402
3999 REM **************************
4000 IF SS$<>"#B1" THEN 5000
4010 GOSUB 600:CN=0:HO=0:VE=0:SR$=MID$(S$,4):GOSUB 650
4019 REM Aussenringraeume
4020 D=0.05:G=0.3:HK=0.5:VK=0.5:SX=0
4030 FOR I=0 TO 28 STEP 4
4040 FOR J=0 TO 32 STEP 2
4050 HO=P(0,J)*D+P(0,I)*G+HK
4060 VE=P(1,J)*D+P(1,I)*G+VK
4070 IF J THEN GOSUB 630:GOTO 4090
4080 GOSUB 620
4090 NEXT J
4100 NEXT I
4149 REM Aussenring
4150 M=2*P/64
4160 FOR I=0.29 TO 0.31 STEP 0.019
4170 FOR J=0 TO 7
4180 FOR K=2 TO 5
4190 L=J*8+K
4200 HO=SIN(L*M)*I*VZ+HK
4210 VE=COS(L*M)*I+VK
4220 GOSUB 620
4230 HO=SIN((L+1)*M)*I*VZ+HK
4240 VE=COS((L+1)*M)*I+VK
4250 GOSUB 630
4260 GOSUB 9500
4270 NEXT K
4280 NEXT J
4290 NEXT I
4299 REM Mittelachse
4300 D=0.08
4310 FOR I=0 TO 32
4320 J=I:GOSUB 5600
4340 IF I THEN GOSUB 630:GOTO 4360
4350 GOSUB 620
4360 NEXT I
4369 REM Speichen
4370 D=0.3:G=0.08:F=0.25
4380 FOR I=0 TO (2*P) STEP P/4
4390 FOR J=-0.5 TO 0.5 STEP R
4400 HO=SIN(I+J*G)*F*VZ+HK
4410 VE=COS(I+J*G)*F+VK
4420 GOSUB 620
4430 HO=SIN(I+J*D)*G*VZ+HK
4440 VE=COS(I+J*D)*G+VK
4450 GOSUB 630
4460 NEXT J
4470 NEXT I
4499 REM Beschriftung
4500 D=0.3:VK=VK-0.02
4510 FOR I=0 TO 7
4520 J=I*4:GOSUB 5600
4540 SR=I+1:GOSUB 300:GOSUB 650
4550 NEXT I
4560 HO=HK-0.01:VK=VK+0.02:VE=VK-0.07
4570 SR$="E":GOSUB 650
4580 HO=HK-0.04:VE=VK-0.02
4590 SR$="402":GOSUB 650
4649 REM Blinken Sektion 3
4650 HO=P(0,8)*D+HK:VE=P(1,8)*D+VK-0.02
4660 F=60:X$="3":GOSUB 200
4670 FOR I=0 TO 1
4680 CN=I:SR$=X$:GOSUB 650
4690 FOR J=0 TO 2
4700 CN=0:IF (F) THEN F=F-1
4710 IF F=1 THEN GOSUB 3600
4720 IF SX>1000 THEN SD=2:GOSUB 450:GOTO 4750
4730 GOSUB 9500
4740 GOSUB 200
4750 IF (IN) THEN J=2:I=1
4760 NEXT J
4770 NEXT I
4780 IF (IN) THEN 2000
4790 GOTO 4670
4997 REM **************************
4998 REM         LABOR-9
4999 REM **************************
5000 IF SS$<>"#B2" THEN 6000
5010 GOSUB 600:CN=0
5020 HO=0:VE=0:SR$=MID$(S$,4):GOSUB 650
5030 D=0.4:HK=0.5:VK=0.5
5039 REM Sektion 3
5040 FOR I=0 TO 32
5050 J=I:GOSUB 5600
5060 IF I THEN GOSUB 630:GOTO 5080
5070 GOSUB 620
5080 NEXT I
5089 REM Raumaufteilung Sektion 3
5090 FOR I=1 TO 15 STEP 2
5100 J=I:GOSUB 5600:GOSUB 620
5110 J=32-I:GOSUB 5600:GOSUB 630
5120 J=I+16:GOSUB 5600:GOSUB 630
5130 J=I:GOSUB 5600:GOSUB 620
5140 J=16-I:GOSUB 5600:GOSUB 630
5150 NEXT I
5160 FOR J=22 TO 26
5170 IF J=24 THEN 5200
5180 GOSUB 5600:GOSUB 620
5190 HO=0:GOSUB 630
5200 NEXT J
5299 REM Verbindungsgaenge
5300 FOR HO=0 TO (HK-D*VZ) STEP 0.05
5310 VE=P(1,22)*D+VK:GOSUB 620
5320 VE=P(1,23)*D+VK:GOSUB 630
5330 VE=P(1,25)*D+VK:GOSUB 620
5340 VE=P(1,26)*D+VK:GOSUB 630
5350 NEXT HO
5400 READ X$
5410 FOR I=1 TO LEN(X$) STEP 2
5420 J=VAL(MID$(X$,I,2))
5430 K=0:IF I<9 THEN K=R
5440 GOSUB 5600:GOSUB 620
5450 VE=K:GOSUB 630
5460 NEXT I
5479 REM Blinken LABOR-9
5480 F=20:GOSUB 200
5500 HO=0.7:VE=0.33:X$="9"
5510 FOR I=0 TO 1
5520 CN=I:SR$=X$:GOSUB 650
5530 IF F THEN F=F-1
5540 IF F=1 THEN CN=0:GOSUB 3600:GOTO 5570
5550 SD=5:GOSUB 450
5560 IF (IN) THEN I=1
5570 NEXT I
5580 IF (IN) THEN 2000
5590 GOTO 5510
5599 REM UP Kreispunkte
5600 HO=P(0,J)*D+HK
5610 VE=P(1,J)*D+VK
5620 RETURN
5997 REM **************************
5998 REM         Weintraube
5999 REM **************************
6000 IF MID$(S$,1,3)<>"#B3" THEN 7000
6010 GOSUB 600:CN=0
6020 X$=MID$(S$,4)
6030 READ Y$:GOSUB 6400
6040 G=0.01:K=0.035:D=G+K
6049 REM Trauben
6050 FOR HK=0.35 TO 0.65 STEP D*2*VZ
6060 FOR VK=0.3 TO 0.9-D STEP D*2
6070 IF ((VK<0.33) OR (VK>0.8)) AND ((HK<0.4) OR (HK>0.6)) THEN 6090
6080 GOSUB 6500:GOSUB 260:D=RV*G+K
6090 NEXT VK
6100 NEXT HK
6109 REM Stiel
6110 HO=0.51:VE=0.25:GOSUB 620
6120 HO=0.55:VE=0.1:GOSUB 630
6130 HO=0.53:GOSUB 630
6140 HO=0.49:VE=0.25:GOSUB 630
6150 CN=1:GOSUB 6400
6160 CN=0:VE=0:READ SR$:GOSUB 650
6170 GOSUB 250:GOSUB 200
6180 SD=50:GOSUB 450
6190 IF (IN) THEN 2000
6200 GOSUB 3600
6210 GOSUB 210
6220 GOTO 2000
6399 REM SCHRIFT
6400 HO=0:VE=0:SR$=X$:GOSUB 650
6410 VE=0.05:SR$=Y$:GOSUB 650
6420 RETURN
6499 REM Weintrauben malen
6500 FOR J=0 TO 32 STEP 2
6510 GOSUB 5600
6520 IF J THEN GOSUB 630:GOTO 6540
6530 GOSUB 620
6540 NEXT J
6550 RETURN
6997 REM **************************
6998 REM         Alkohol
6999 REM **************************
7000 GOSUB 600:CN=0
7010 HO=0:VE=0:SR$=MID$(S$,4):GOSUB 650
7020 READ X$:K=0
7030 D=0.2:VK=0.5:HK=0.35
7040 S=0:E=16:GOSUB 7500
7050 S=22:E=26:GOSUB 7500:REM C1
7060 HK=0.65:S=16:E=32:GOSUB 7500
7070 S=6:E=10:GOSUB 7500:REM C2
7080 D=0.15:HK=0.25:VK=0.3:S=0:E=32:GOSUB 7500:REM H1
7090 VK=0.5:HK=0.15:S=16:GOSUB 7500:REM H2
7100 VK=0.7:HK=0.25:S=0:GOSUB 7500:REM H3
7110 VK=0.3:HK=0.75:GOSUB 7500:REM H4
7120 VK=0.5:HK=0.85:E=16:GOSUB 7500:REM H5
7130 VK=0.7:HK=0.75:S=8:E=32:GOSUB 7500:REM O(H)
7140 VK=0.84:HK=0.85:S=0:GOSUB 7500:REM (O)H
7150 CN=1:HO=0:VE=0:SR$=MID$(S$,4):GOSUB 650
7160 CN=0:READ SR$:GOSUB 650
7170 GOSUB 250:GOSUB 200
7180 SD=50:GOSUB 450
7190 IF (IN) THEN 2000
7200 GOSUB 3600
7210 GOSUB 210
7220 GOTO 2000
7499 REM UP zeichnen Molekuele
7500 FOR J=S TO E
7510 GOSUB 5600
7520 IF J=S THEN GOSUB 620:GOTO 7540
7530 GOSUB 630
7540 NEXT J
7550 K=K+1:SR$=MID$(X$,K,1)
7560 HO=HK:VE=VK-0.02:GOSUB 650
7570 GOSUB 1070
7580 RETURN
8997 REM **********************
8998 REM       TITELBILD
8999 REM **********************
9000 D=0.1:SX=0
9010 GOSUB 600:HO=0:VE=0:GOSUB 620
9020 HO=R:GOSUB 630:VE=R:GOSUB 630
9030 HO=0:GOSUB 630:VE=0:GOSUB 630
9040 HO=D:VE=D:READ SR$:GOSUB 650
9050 L$=SR$
9099 REM Sonne
9100 HK=0.61:VK=0.65:J=D*VZ
9110 FOR I=0 TO P STEP 1/VG/D
9120 GOSUB 9500
9130 HO=SIN(I+P)*J+HK
9140 VE=COS(I+P)*D+VK
9150 GOSUB 620
9160 HO=SIN(I)*J+HK
9170 VE=COS(I+P)*D+VK
9180 GOSUB 630
9190 NEXT I
9199 REM Umlaufbahn
9200 G=0.6:J=2*P/32:HK=0.52:VK=G
9210 FOR I=0 TO 32
9220 K=I*J
9230 P(0,I)=SIN(K)*VZ
9240 HO=P(0,I)*G+HK
9250 P(1,I)=COS(K)
9260 VE=P(1,I)*D+VK
9270 CN=0:IF I<3 THEN CN=1
9280 IF I THEN GOSUB 630:GOTO 9300
9290 GOSUB 620
9300 NEXT I
9309 REM Umlauf
9310 X$="*":F=1:GOSUB 200
9320 FOR I=1 TO 32
9330 M=0:IF I<2 THEN M=1
9340 HO=P(0,I)*G+HK:VE=P(1,I)*D+VK-0.02
9350 CN=M:SR$=X$:GOSUB 650
9360 IF (I=32) AND (F) THEN F=0:GOSUB 3600:GOTO 9430
9370 FOR J=0 TO 4
9380 IF SX>2000 THEN SD=2:GOSUB 450:GOTO 9410
9390 CN=0:GOSUB 9500
9400 GOSUB 200
9410 IF (IN) THEN J=4:I=32
9420 NEXT J
9430 CN=1-M:SR$=X$:GOSUB 650
9440 NEXT I
9450 IF (IN) THEN RETURN
9460 GOTO 9320
9499 REM STERNE
9500 CN=0:SX=SX+1
9510 H=HO:V=VE
9520 GOSUB 260:HO=RV*R
9530 GOSUB 260:VE=RV*R
9540 GOSUB 620
9550 HO=H:VE=V
9560 RETURN
24999 REM DATA 'S
25000 DATA "*** LABOR-9 / TEIL 1 ***"
25010 DATA " Die Story:","#ZV ==========","#ZV  "
25020 DATA "#ZVWir schreiben das Jahr 2247."
25030 DATA "#ZVIn einer guenstigen Umlaufbahn"
25040 DATA "um die SONNE befindet sich die"
25050 DATA "Raumstation EXPERIMENT-402."
25060 DATA "#B1Raumstation EXPERIMENT-402"
25070 DATA "Auf EXPERIMENT-402 werden"
25080 DATA "wissenschaftliche Experimente"
25090 DATA "durchgefuehrt@ die aus"
25100 DATA "oekologischen Gruenden auf der"
25110 DATA "ERDE nicht vertretbar sind."
25120 DATA "#ZVDer entstehende Muell wird in"
25130 DATA "Containern entsorgt@ die in die"
25140 DATA "SONNE geschossen werden."
25150 DATA "#ZVIn Sektion 3 liegt die"
25160 DATA "BIOLOGIESTATION mit LABOR-9."
25170 DATA "#B2BIOLOGIESTATION mit LABOR-9"
25180 DATA "3031010218171514","Um auf Grund der"
25190 DATA "Gefaehrlichkeit der Experimente@"
25200 DATA "die Raeume gegen UNBEFUGTE und"
25210 DATA "ungebetene GAESTE zu sichern@"
25220 DATA "sind die Tueren mit"
25230 DATA "SICHERHEITSSCHLOESSERN und"
25240 DATA "CODEWOERTERN gesichert."
25250 DATA "#ZVAlle Raeume der Labore"
25260 DATA "reagieren auf den"
25270 DATA "4. Fehlversuch beim Oeffnen der"
25280 DATA "SUPER-Schloesser"
25290 DATA "(--CODEWOERTER--) und der"
25300 DATA "SICHERHEITS-Schloesser"
25310 DATA "(--SICHERHEITSSCHLUESSEL--) mit"
25320 DATA "Absprengen eines Deckels in das"
25330 DATA "All."
25340 DATA "#ZVEs entsteht das gefuerchtete"
25350 DATA "kosmische Vakuum@ in dem kein"
25360 DATA "biologischer Organismus"
25370 DATA "lebensfaehig ist."
25380 DATA "#ZV  ","#ZV  "
25390 DATA "#ZV   In LABOR-9 arbeiten :"
25400 DATA "#ZV  ","#ZV  "
25410 DATA "#ZV   *-----------------------*"
25420 DATA "#ZV   !                       !"
25430 DATA "#ZV   ! Prof. EDGAR MARK (56) !"
25440 DATA "#ZV   !                       !"
25450 DATA "#ZV   !       AMERIKA         !"
25460 DATA "#ZV   !                       !"
25470 DATA "#ZV   *-----------------------*"
25480 DATA "#ZV  ","#ZV  "
25490 DATA "#ZV    - und sein Assistent :"
25500 DATA "#ZV  ","#ZV  "
25510 DATA "#ZV   *-----------------------*"
25520 DATA "#ZV   !                       !"
25530 DATA "#ZV   !  ERIK WEINSTEIN (29)  !"
25540 DATA "#ZV   !                       !"
25550 DATA "#ZV   !     DEUTSCHLAND       !"
25560 DATA "#ZV   !                       !"
25570 DATA "#ZV   *-----------------------*"
25580 DATA "#ZV  ","#ZV  "
25600 DATA "#ZVSie experimentieren mit neuen"
25610 DATA "Weinsorten und Weinhefen."
25620 DATA "#ZVVorgestern ist ihnen der grosse"
25630 DATA "Durchbruch gelungen. Mit Hilfe"
25640 DATA "elektrostatisch stimulierter"
25650 DATA "Genmanipulation unter Einfluss"
25660 DATA "der Schwerelosigkeit ist ihnen"
25670 DATA "die Zuechtung von"
25680 DATA "regelmaessig gewachsenen"
25690 DATA "Weintrauben geglueckt@ die"
25700 DATA "annaehernd die Groesse eines"
25710 DATA "Golfballs haben und deren"
25720 DATA "Lieblichkeit alles bisher"
25730 DATA "Bekannte uebertrifft."
25740 DATA "#B3PRACHTEXEMPLAR einer"
25750 DATA "regelmaessigen Weintraube"
25760 DATA "    Herrlich nicht wahr?"
25770 DATA "#ZVSeit gestern ist ERIK"
25780 DATA "wie besessen von der Idee@"
25790 DATA "daraus WEIN herzustellen.","#ZVProf."
25800 DATA "MARK ist jedoch der Meinung@"
25810 DATA "dass das Experiment mit diesem"
25820 DATA "Zuechtungserfolg beendet ist."
25830 DATA "Er moechte abschliessend noch"
25840 DATA "toxikologische Untersuchungen"
25850 DATA "auf der Raumstation und spaeter"
25860 DATA "weitere Versuche und spezielle"
25870 DATA "Tests auf der ERDE durchfuehren."
25880 DATA "#ZVERIK hat heimlich HEFE"
25890 DATA "in einem Laborglas angesetzt."
25900 DATA "#ZVBeim naechtlichen Gruebeln"
25910 DATA "merkt er@ dass es viel zu viel"
25920 DATA "war.","#ZVWas ist@ wenn die Hefe sich"
25930 DATA "ausdehnt und das Laborglas"
25940 DATA "zerdrueckt?","#ZVWas passiert@ wenn"
25950 DATA "sie sich bei Schwerelosigkeit"
25960 DATA "im gesamten Labor ausbreitet und"
25970 DATA "mit anderen harmlosen Substanzen"
25980 DATA "gefaehrliche Verbindungen eingeht?"
25990 DATA "#B4... gefaehrlich wie z. B. ..."
26000 DATA "CCCCHHHHHOH"
26010 DATA "--- A L K O H O L ? ? ? ? ---"
26020 DATA "Nicht auszudenken!"
26030 DATA "#ZVERIK muss noch heute Nacht"
26040 DATA "in's LABOR-9!!!"
26050 DATA "#ZVKoste es was es wolle!"
26060 DATA "#ZV  ","#ZF-","#ZV  "
26070 DATA "#ZVBitte hilf ihm dabei!!"
26080 DATA "Denke an die grausamen"
26090 DATA "Konsequenzen@ falls eines der"
26100 DATA "Schloesser mehrmals mit einem"
26110 DATA "falschen Schluessel betaetigt"
26120 DATA "wird!!!"
26200 DATA "#ZVPraege DIR gut die Codewoerter"
26210 DATA "ein@ sonst wird ERIK auf ewig"
26220 DATA "zum Kometen und DU bist daran"
26230 DATA "mitschuldig!!!"
26240 DATA "#ZVNun fange endlich an@ denn"
26250 DATA "ERIK ist auf DEINE Hilfe"
26260 DATA "angewiesen. Er ist zu"
26270 DATA "schusselig@ die richtigen"
26280 DATA "Schluessel seines grossen"
26290 DATA "Schluesselbundes und die"
26300 DATA "jeweiligen Codewoerter@ die zu"
26310 DATA "bestimmten Tueren gehoeren@"
26320 DATA "richtig anzuwenden."
26330 DATA "#ZV  ","#ZF-","#ZV  "
26340 DATA "#ZVNun hoere endlich auf zu"
26350 DATA "gucken und zu lesen und lade"
26360 DATA "den Teil 2 von LABOR-9 in den"
26370 DATA "Computer ein!!!"
26380 DATA "#ZVERIK schafft es nicht ohne"
26390 DATA "DEINE HILFE!!!"
26400 DATA "#ZV  ","#ZV  "
26410 DATA "#ZV  ","#ZV  "
26420 DATA "#END"
26430 DATA "Fange endlich an !! >>"
32000 REM *-------------------*
32010 REM !    Lutz Mueller   !
32020 REM !Roggenfelderstr. 50!
32030 REM !   O-2802 DOEMITZ  !
32040 REM !     08.03.1992    !
32050 REM !  auf ATARI 800 XE !
32060 REM !-------------------!
32070 REM !Wenn das Programm  !
32080 REM !gefaellt oder nicht!
32090 REM !schreiben Sie mir !!
32100 REM *-------------------*
32110 REM
32120 REM Erstausstrahlung: Deutschlandsender Kultur
32130 REM-spezial 920401